JBrainTrend1Stop_Alert: O Indicador de Tendência para MetaTrader 5 com Alertas

JBrainTrend1Stop é um indicador de tendência que traz uma série de funcionalidades práticas, como alertas, e-mails e notificações push, para te ajudar a não perder nenhuma oportunidade no mercado.

Recentemente, algumas melhorias foram implementadas no código do indicador para adicionar essas funcionalidades. Vamos conferir as principais alterações:

Adicionamos novos parâmetros de entrada:

input uint NumberofBar=1;//Número da barra para o sinal
input bool SoundON=true; //Habilitar alertas
input uint NumberofAlerts=2;//Número de alertas
input bool EMailON=false; //Habilitar envio de e-mails
input bool PushON=false; //Habilitar envio de notificações para dispositivos móveis

Três novas funções foram adicionadas ao final do código do indicador: BuySignal(), SellSignal() e GetStringTimeframe().
//+------------------------------------------------------------------+
//| Função de sinal de compra                                              |
//+------------------------------------------------------------------+
void BuySignal(string SignalSirname,      // texto do nome do indicador para mensagens de e-mail e push
               double &BuyArrow[],        // buffer do indicador com sinais de tendência de alta
               double &SellArrow[],       // buffer do indicador com sinais de tendência de baixa
               const int Rates_total,     // número atual de barras
               const int Prev_calculated, // número de barras no tick anterior
               const double &Close[],     // preço de fechamento
               const int &Spread[])       // spread
  {
//---
   static uint counter=0;
   if(Rates_total!=Prev_calculated) counter=0;

   bool BuySignal=false;
   bool SeriesTest=ArrayGetAsSeries(BuyArrow);
   int index,index1;
   if(SeriesTest)
     {
      index=int(NumberofBar);
      index1=index+1;
     }
   else
     {
      index=Rates_total-int(NumberofBar)-1;
      index1=index-1;
     }
   if(SellArrow[index1] && SellArrow[index1]!=EMPTY_VALUE && BuyArrow[index] && BuyArrow[index]!=EMPTY_VALUE) BuySignal=true;
   if(BuySignal && counter<=NumberofAlerts)
     {
      counter++;
      MqlDateTime tm;
      TimeToStruct(TimeCurrent(),tm);
      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
      SeriesTest=ArrayGetAsSeries(Close);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      double Ask=Close[index];
      double Bid=Close[index];
      SeriesTest=ArrayGetAsSeries(Spread);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      Bid+=_Point*Spread[index];
      string sAsk=DoubleToString(Ask,_Digits);
      string sBid=DoubleToString(Bid,_Digits);
      string sPeriod=GetStringTimeframe(ChartPeriod());
      if(SoundON) Alert("Sinal de COMPRA Ask=",Ask," Bid=",Bid," hora atual=",text," Símbolo=",Symbol()," Período=",sPeriod);
      if(EMailON) SendMail(SignalSirname+": alerta de sinal de COMPRA","Sinal de COMPRA em Ask="+sAsk+", Bid="+sBid+", Data="+text+" Símbolo="+Symbol()+" Período="+sPeriod);
      if(PushON) SendNotification(SignalSirname+": Sinal de COMPRA em Ask="+sAsk+", Bid="+sBid+", Data="+text+" Símbolo="+Symbol()+" Período="+sPeriod);
     }

//---
  }
//+------------------------------------------------------------------+
//| Função de sinal de venda                                             |
//+------------------------------------------------------------------+
void SellSignal(string SignalSirname,      // texto do nome do indicador para mensagens de e-mail e push
                double &SellArrow[],       // buffer do indicador com sinais de tendência de baixa
                double &BuyArrow[],        // buffer do indicador com sinais de tendência de alta
                const int Rates_total,     // número atual de barras
                const int Prev_calculated, // número de barras no tick anterior
                const double &Close[],     // preço de fechamento
                const int &Spread[])       // spread
  {
//---
   static uint counter=0;
   if(Rates_total!=Prev_calculated) counter=0;

   bool SellSignal=false;
   bool SeriesTest=ArrayGetAsSeries(SellArrow);
   int index,index1;
   if(SeriesTest)
     {
      index=int(NumberofBar);
      index1=index+1;
     }
   else
     {
      index=Rates_total-int(NumberofBar)-1;
      index1=index-1;
     }
   if(BuyArrow[index1] && BuyArrow[index1]!=EMPTY_VALUE && SellArrow[index] && SellArrow[index]!=EMPTY_VALUE) SellSignal=true;
   if(SellSignal && counter<=NumberofAlerts)
     {
      counter++;
      MqlDateTime tm;
      TimeToStruct(TimeCurrent(),tm);
      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
      SeriesTest=ArrayGetAsSeries(Close);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      double Ask=Close[index];
      double Bid=Close[index];
      SeriesTest=ArrayGetAsSeries(Spread);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      Bid+=_Point*Spread[index];
      string sAsk=DoubleToString(Ask,_Digits);
      string sBid=DoubleToString(Bid,_Digits);
      string sPeriod=GetStringTimeframe(ChartPeriod());
      if(SoundON) Alert("Sinal de VENDA Ask=",Ask," Bid=",Bid," hora atual=",text," Símbolo=",Symbol()," Período=",sPeriod);
      if(EMailON) SendMail(SignalSirname+": alerta de sinal de VENDA","Sinal de VENDA em Ask="+sAsk+", Bid="+sBid+", Data="+text+" Símbolo="+Symbol()+" Período="+sPeriod);
      if(PushON) SendNotification(SignalSirname+": Sinal de VENDA em Ask="+sAsk+", Bid="+sBid+", Data="+text+" Símbolo="+Symbol()+" Período="+sPeriod);
     }
//---
  }
//+------------------------------------------------------------------+
//|  Obtendo o timeframe como string                               |
//+------------------------------------------------------------------+
string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)
  {
//----
   return(StringSubstr(EnumToString(timeframe),7,-1));
//----
  }
Algumas chamadas para as funções BuySignal() e SellSignal() foram adicionadas após os ciclos de cálculo do indicador no bloco OnCalculate().
//---
   BuySignal("JBrainTrend1Stop_Alert",BuyStopBuffer,SellStopBuffer,rates_total,prev_calculated,close,spread);
   SellSignal("JBrainTrend1Stop_Alert",SellStopBuffer,BuyStopBuffer,rates_total,prev_calculated,close,spread);
//---

Os buffers BuyStopBuffer e SellStopBuffer são usados para armazenar os sinais de tendência de alta e baixa (linhas de stop para compras e vendas). Um valor zero ou EMPTY_VALUE deve estar presente nos buffers do indicador se não houver uma tendência apropriada.

Acredita-se que apenas uma chamada para as funções BuySignal() e SellSignal() será utilizada no bloco OnCalculate() do código do indicador.

Coloque o arquivo compilado do indicador JMA.mq5 na pasta MQL5\Indicators.

Fig.1. Indicador JBrainTrend1Stop_Alert no gráfico

Fig.2. Indicador JBrainTrend1Stop_Alert. Gerando alertas

JBrainTrend1Stop_Alert: O Indicador de Tendência para MetaTrader 5 com Alertas

Publicações relacionadas