होम तकनीकी संकेतक पोस्ट

iRSISignAlert - MetaTrader 5 के लिए सिग्नल इंडिकेटर

Mike • 2016-07-20 23:43
2 0 0
संलग्नक
15840.zip (3.1 KB, डाउनलोड 0 बार)

iRSISignAlert एक सेमाफोर एरो सिग्नल इंडिकेटर है जो क्लासिक रिलेटिव स्ट्रेंथ इंडेक्स (RSI) ऑस्सीलेटर पर आधारित है। यह ओवरबॉट और ओवरसोल्ड क्षेत्रों से बाहर निकलने के समय सिग्नल प्रदान करता है और साथ ही अलर्ट, ईमेल और मोबाइल डिवाइस पर पुश-नोटिफिकेशन भेजने की सुविधा भी देता है।

इस इंडिकेटर कोड में कुछ बदलाव किए गए हैं ताकि अलर्ट, ईमेल संदेश और पुश-नोटिफिकेशन को सक्षम किया जा सके:

  1. नए इनपुट पैरामीटर जोड़े गए हैं:
    input uint NumberofBar=1;// सिग्नल के लिए बार संख्या
input bool SoundON=true; // अलर्ट सक्षम करें
input uint NumberofAlerts=2;// अलर्ट की संख्या
input bool EMailON=false; // सिग्नल के लिए ईमेल सक्षम करें
input bool PushON=false; // मोबाइल डिवाइस पर सिग्नल भेजें
  2. इंडिकेटर कोड के अंत में तीन नई फ़ंक्शंस जोड़ी गई हैं: BuySignal(), SellSignal() और GetStringTimeframe()
    //+------------------------------------------------------------------+
//| खरीद सिग्नल फ़ंक्शन                                              |
//+------------------------------------------------------------------+
void BuySignal(string SignalSirname,      // ईमेल और पुश संदेशों के लिए इंडिकेटर नाम का पाठ
               double &BuyArrow[],        // खरीद सिग्नल के लिए इंडिकेटर बफर
               const int Rates_total,     // वर्तमान बार की संख्या
               const int Prev_calculated, // पिछले टिक पर बार की संख्या
               const double &Close[],     // क्लोज प्राइस
               const int &Spread[])       // स्प्रेड
  {
//---
   static uint counter=0;
   if(Rates_total!=Prev_calculated) counter=0;

   bool BuySignal=false;
   bool SeriesTest=ArrayGetAsSeries(BuyArrow);
   int index;
   if(SeriesTest) index=int(NumberofBar);
   else index=Rates_total-int(NumberofBar)-1;
   if(NormalizeDouble(BuyArrow[index],_Digits) && BuyArrow[index]!=EMPTY_VALUE) BuySignal=true;
   if(BuySignal && counter<=NumberofAlerts)
     {
      counter++;
      MqlDateTime tm;
      TimeToStruct(TimeCurrent(),tm);
      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
      SeriesTest=ArrayGetAsSeries(Close);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      double Ask=Close[index];
      double Bid=Close[index];
      SeriesTest=ArrayGetAsSeries(Spread);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      Bid+=Spread[index];
      string sAsk=DoubleToString(Ask,_Digits);
      string sBid=DoubleToString(Bid,_Digits);
      string sPeriod=GetStringTimeframe(ChartPeriod());
      if(SoundON) Alert("BUY signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);
      if(EMailON) SendMail(SignalSirname+": BUY signal alert","BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
      if(PushON) SendNotification(SignalSirname+": BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
     }
//---
  }
//+------------------------------------------------------------------+
//| बिक्री सिग्नल फ़ंक्शन                                               |
//+------------------------------------------------------------------+
void SellSignal(string SignalSirname,      // ईमेल और पुश संदेशों के लिए इंडिकेटर नाम का पाठ
                double &SellArrow[],       // बिक्री सिग्नल के लिए इंडिकेटर बफर
                const int Rates_total,     // वर्तमान बार की संख्या
                const int Prev_calculated, // पिछले टिक पर बार की संख्या
                const double &Close[],     // क्लोज प्राइस
                const int &Spread[])       // स्प्रेड
  {
//---
   static uint counter=0;
   if(Rates_total!=Prev_calculated) counter=0;

   bool SellSignal=false;
   bool SeriesTest=ArrayGetAsSeries(SellArrow);
   int index;
   if(SeriesTest) index=int(NumberofBar);
   else index=Rates_total-int(NumberofBar)-1;
   if(NormalizeDouble(SellArrow[index],_Digits) && SellArrow[index]!=EMPTY_VALUE) SellSignal=true;
   if(SellSignal && counter<=NumberofAlerts)
     {
      counter++;
      MqlDateTime tm;
      TimeToStruct(TimeCurrent(),tm);
      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
      SeriesTest=ArrayGetAsSeries(Close);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      double Ask=Close[index];
      double Bid=Close[index];
      SeriesTest=ArrayGetAsSeries(Spread);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      Bid+=Spread[index];
      string sAsk=DoubleToString(Ask,_Digits);
      string sBid=DoubleToString(Bid,_Digits);
      string sPeriod=GetStringTimeframe(ChartPeriod());
      if(SoundON) Alert("SELL signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);
      if(EMailON) SendMail(SignalSirname+": SELL signal alert","SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
      if(PushON) SendNotification(SignalSirname+": SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
     }
//---
  }
//+------------------------------------------------------------------+
//|  समय-सीमा को स्ट्रिंग के रूप में प्राप्त करना                             |
//+------------------------------------------------------------------+
string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)
  {
//----
   return(StringSubstr(EnumToString(timeframe),7,-1));
//----
  }
  3. BuySignal() और SellSignal() फ़ंक्शन को OnCalculate() ब्लॉक के बाद जोड़ा गया है:
    BuySignal("iWPRSign",BuyBuffer,rates_total,prev_calculated,close,spread);
    SellSignal("iWPRSign",SellBuffer,rates_total,prev_calculated,close,spread);

जहां BuyBuffer और SellBuffer खरीद और बिक्री सिग्नल को स्टोर करने के लिए इंडिकेटर बफर के नाम हैं। इंडिकेटर बफर में खाली मान या तो ज़ीरो या EMPTY_VALUE होना चाहिए।

यह मान लिया गया है कि BuySignal() और SellSignal() फ़ंक्शन का केवल एक ही कॉल इंडिकेटर कोड के OnCalculate() ब्लॉक में उपयोग किया जाएगा।

Fig.1. The iRSISignAlert indicator on the chart

Fig.1. iRSISignAlert इंडिकेटर चार्ट पर

Fig.2. The iRSISignAlert indicator. Generating alerts.

Fig.2. iRSISignAlert इंडिकेटर अलर्ट उत्पन्न कर रहा है।

संबंधित पोस्ट

सूची
टिप्पणी (0)