Iin_MA_Signal_Alert: Il Tuo Nuovo Indice di Segnale per MetaTrader 5

Autore originale: Iin Zulkarnainn

Se sei un trader che utilizza MetaTrader 5, probabilmente conosci già l'importanza di avere indicatori affidabili. Oggi parliamo del Iin_MA_Signal, un indicatore semaforico che offre avvisi, email e notifiche push per tenerti sempre aggiornato sulle opportunità di trading.

Recentemente, sono state apportate alcune modifiche al codice dell'indicatore per implementare queste funzionalità. Ecco i dettagli:

1. Introdotti nuovi parametri di input:

   input uint NumberofBar=1;//Numero di barre per il segnale
   input bool SoundON=true; //Abilita gli avvisi
   input uint NumberofAlerts=2;//Numero di avvisi
   input bool EMailON=false; //Abilita l'invio di email per il segnale
   input bool PushON=false; //Abilita l'invio di notifiche sul dispositivo mobile
   

2. Aggiunte tre nuove funzioni al codice dell'indicatore: BuySignal(), SellSignal() e GetStringTimeframe()

   //+------------------------------------------------------------------+
   //| Funzione di segnale di acquisto                                   |
   //+------------------------------------------------------------------+
   void BuySignal(string SignalSirname,// testo del nome dell'indicatore per email e messaggi push
         double &BuyArrow[],// buffer dell'indicatore con segnali di acquisto
         const int Rates_total,// il numero attuale di barre
         const int Prev_calculated,// il numero di barre al tick precedente
         const double &Close[],// prezzo di chiusura
         const int &Spread[])// spread
     {
   //---
     static uint counter=0;
     if(Rates_total!=Prev_calculated) counter=0;
   
     bool BuySignal=false;
     bool SeriesTest=ArrayGetAsSeries(BuyArrow);
     int index;
     if(SeriesTest) index=int(NumberofBar);
     else index=Rates_total-int(NumberofBar)-1;
     if(NormalizeDouble(BuyArrow[index],_Digits) && BuyArrow[index]!=EMPTY_VALUE) BuySignal=true;
     if(BuySignal && counter<=NumberofAlerts)
       {
         counter++;
         MqlDateTime tm;
         TimeToStruct(TimeCurrent(),tm);
         string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
         SeriesTest=ArrayGetAsSeries(Close);
         if(SeriesTest) index=int(NumberofBar);
         else index=Rates_total-int(NumberofBar)-1;
         double Ask=Close[index];
         double Bid=Close[index];
         SeriesTest=ArrayGetAsSeries(Spread);
         if(SeriesTest) index=int(NumberofBar);
         else index=Rates_total-int(NumberofBar)-1;
         Bid+=Spread[index];
         string sAsk=DoubleToString(Ask,_Digits);
         string sBid=DoubleToString(Bid,_Digits);
         string sPeriod=GetStringTimeframe(ChartPeriod());
         if(SoundON) Alert("BUY signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": BUY signal alert","BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
       }
   //---
     }
   //+------------------------------------------------------------------+
   //| Funzione di segnale di vendita                                   |
   //+------------------------------------------------------------------+
   void SellSignal(string SignalSirname,// testo del nome dell'indicatore per email e messaggi push
         double &SellArrow[],// buffer dell'indicatore con segnali di vendita
         const int Rates_total,// il numero attuale di barre
         const int Prev_calculated,// il numero di barre al tick precedente
         const double &Close[],// prezzo di chiusura
         const int &Spread[])// spread
     {
   //---
     static uint counter=0;
     if(Rates_total!=Prev_calculated) counter=0;
   
     bool SellSignal=false;
     bool SeriesTest=ArrayGetAsSeries(SellArrow);
     int index;
     if(SeriesTest) index=int(NumberofBar);
     else index=Rates_total-int(NumberofBar)-1;
     if(NormalizeDouble(SellArrow[index],_Digits) && SellArrow[index]!=EMPTY_VALUE) SellSignal=true;
     if(SellSignal && counter<=NumberofAlerts)
       {
         counter++;
         MqlDateTime tm;
         TimeToStruct(TimeCurrent(),tm);
         string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
         SeriesTest=ArrayGetAsSeries(Close);
         if(SeriesTest) index=int(NumberofBar);
         else index=Rates_total-int(NumberofBar)-1;
         double Ask=Close[index];
         double Bid=Close[index];
         SeriesTest=ArrayGetAsSeries(Spread);
         if(SeriesTest) index=int(NumberofBar);
         else index=Rates_total-int(NumberofBar)-1;
         Bid+=Spread[index];
         string sAsk=DoubleToString(Ask,_Digits);
         string sBid=DoubleToString(Bid,_Digits);
         string sPeriod=GetStringTimeframe(ChartPeriod());
         if(SoundON) Alert("SELL signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": SELL signal alert","SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
       }
   //---
     }
   //+------------------------------------------------------------------+
   //|  Ottenere il timeframe come stringa                               |
   //+------------------------------------------------------------------+
   string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)
     {
   //----
     return(StringSubstr(EnumToString(timeframe),7,-1));
   //----
     }

3. Aggiunti alcuni richiami alle funzioni BuySignal() e SellSignal() dopo i cicli di calcolo dell'indicatore nel blocco OnCalculate():

   //---     
      BuySignal("Iin_MA_Signal_Alert",BuyBuffer,rates_total,prev_calculated,close,spread);
      SellSignal("Iin_MA_Signal_Alert",SellBuffer,rates_total,prev_calculated,close,spread);
   //--- 

Dove BuyBuffer e SellBuffer sono i nomi dei buffer dell'indicatore per memorizzare i segnali di acquisto e vendita. È importante impostare i valori vuoti nei buffer dell'indicatore a zero o a EMPTY_VALUE.

Si presume che ci sarà solo una chiamata alle funzioni BuySignal() e SellSignal() nel blocco OnCalculate() del codice dell'indicatore.

Fig. 1. Iin_MA_Signal_Alert sul grafico

Fig. 2. Iin_MA_Signal_Alert. Generazione di avvisi

Post correlati

• Indice di Volatilità Chaikin: Scegli il Giusto Algoritmo di Smussamento per MetaTrader 5
• Volatilità Stocastica: Indicatore per MetaTrader 5 da Utilizzare sul Grafico
• Notis: L'Indicatore per Misurare la Volatilità su MetaTrader 5
• Utilità per Serie e Informazioni sulle Rate in MetaTrader 5
• Indicatore di Equità e Bilancio per MetaTrader 5: Monitoraggio della Tua Performance di Trading