ColorXdinMA_Alert: Indikator Trend dengan Notifikasi untuk MetaTrader 5 -

Penulis Asli: dimeon

Indikator ColorXdinMA adalah indikator moving average yang dilengkapi dengan fitur notifikasi, email, dan push-notifikasi ke perangkat mobile Anda.

Berikut adalah beberapa perubahan yang dilakukan pada kode indikator ini untuk mengimplementasikan notifikasi, pesan email, dan push-notifikasi:

Pernyataan untuk opsi pembuatan sinyal indikator dideklarasikan di ruang lingkup global sebelum variabel input dideklarasikan.
//+----------------------------------------------------+
//| Enumerasi untuk opsi pembuatan sinyal   |
//+----------------------------------------------------+
enum ENUM_SIGNAL_MODE
  {
   MODE_SIGNAL,  //Sinyal breakout
   MODE_TREND    //Sinyal breakout dan trend
  };
Menambahkan parameter input baru
//---- Variabel input untuk notifikasi
input ENUM_SIGNAL_MODE SignMode=MODE_SIGNAL; //Mode pembuatan sinyal
input uint NumberofBar=1;                    //Jumlah bar untuk menghasilkan sinyal
input bool SoundON=true;                     //Aktifkan notifikasi suara
input uint NumberofAlerts=2;                 //Jumlah notifikasi
input bool EMailON=false;                    //Aktifkan pengiriman email sinyal
input bool PushON=false;                     //Aktifkan pengiriman sinyal ke perangkat mobile
Menambahkan tiga fungsi baru pada akhir kode indikator: BuySignal(), SellSignal(), dan GetStringTimeframe()
//+------------------------------------------------------------------+
//| Fungsi sinyal beli                                            |
//+------------------------------------------------------------------+
void BuySignal(string SignalSirname,// teks dari nama indikator untuk email dan pesan push
               double &ColorArray[],// buffer indeks warna
               int ColorIndex,// indeks warna di buffer indeks warna untuk menghasilkan sinyal
               const int Rates_total,     // jumlah bar saat ini
               const int Prev_calculated, // jumlah bar pada tick sebelumnya
               const double &Close[],     // harga tutup
               const int &Spread[])       // spread
  {
//---
   static uint counter=0;
   if(Rates_total!=Prev_calculated) counter=0;

   bool BuySignal=false;
   bool SeriesTest=ArrayGetAsSeries(ColorArray);
   int index,index1;
   if(SeriesTest)
     {
      index=int(NumberofBar);
      index1=index+1;
     }
   else
     {
      index=Rates_total-int(NumberofBar)-1;
      index1=index-1;
     }
   if(SignMode==MODE_SIGNAL)
     {
      if(ColorArray[index1]!=ColorIndex && ColorArray[index]==ColorIndex) BuySignal=true;
     }
   else
     {
      if(ColorArray[index]==ColorIndex) BuySignal=true;
     }
   if(BuySignal && counter<=NumberofAlerts)
     {
      counter++;
      MqlDateTime tm;
      TimeToStruct(TimeCurrent(),tm);
      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
      SeriesTest=ArrayGetAsSeries(Close);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      double Ask=Close[index];
      double Bid=Close[index];
      SeriesTest=ArrayGetAsSeries(Spread);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      Bid+=_Point*Spread[index];
      string sAsk=DoubleToString(Ask,_Digits);
      string sBid=DoubleToString(Bid,_Digits);
      string sPeriod=GetStringTimeframe(ChartPeriod());
      if(SignMode==MODE_SIGNAL || (SignMode==MODE_TREND && ColorArray[index1]!=ColorIndex))
        {
         if(SoundON) Alert("Sinyal BUY \n Ask=",Ask,"\n Bid=",Bid,"\n waktu=",text,"\n Simbol=",Symbol()," Periode=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": Peringatan sinyal BUY","Sinyal BUY di Ask="+sAsk+", Bid="+sBid+", Tanggal="+text+" Simbol="+Symbol()+" Periode="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": Sinyal BUY di Ask="+sAsk+", Bid="+sBid+", Tanggal="+text+" Simbol="+Symbol()+" Periode="+sPeriod);
        }
      else
        {
         if(SoundON) Alert("Sinyal Up Trend \n Ask=",Ask,"\n Bid=",Bid,"\n waktu=",text,"\n Simbol=",Symbol()," Periode=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": Peringatan sinyal Up Trend","Sinyal Up Trend di Ask="+sAsk+", Bid="+sBid+", Tanggal="+text+" Simbol="+Symbol()+" Periode="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": Sinyal Up Trend di Ask="+sAsk+", Bid="+sBid+", Tanggal="+text+" Simbol="+Symbol()+" Periode="+sPeriod);
        }
     }

//---
  }
//+------------------------------------------------------------------+
//| Fungsi sinyal jual                                             |
//+------------------------------------------------------------------+
void SellSignal(string SignalSirname,// teks dari nama indikator untuk email dan pesan push
                double &ColorArray[],       // buffer indeks warna
                int ColorIndex,             // indeks warna di buffer indeks warna untuk menghasilkan sinyal
                const int Rates_total,     // jumlah bar saat ini
                const int Prev_calculated, // jumlah bar pada tick sebelumnya
                const double &Close[],     // harga tutup
                const int &Spread[])       // spread
  {
//---
   static uint counter=0;
   if(Rates_total!=Prev_calculated) counter=0;

   bool SellSignal=false;
   bool SeriesTest=ArrayGetAsSeries(ColorArray);
   int index,index1;
   if(SeriesTest)
     {
      index=int(NumberofBar);
      index1=index+1;
     }
   else
     {
      index=Rates_total-int(NumberofBar)-1;
      index1=index-1;
     }

   if(SignMode==MODE_SIGNAL)
     {
      if(ColorArray[index1]!=ColorIndex && ColorArray[index]==ColorIndex) SellSignal=true;
     }
   else
     {
      if(ColorArray[index]==ColorIndex) SellSignal=true;
     }
   if(SellSignal && counter<=NumberofAlerts)
     {
      counter++;
      MqlDateTime tm;
      TimeToStruct(TimeCurrent(),tm);
      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
      SeriesTest=ArrayGetAsSeries(Close);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      double Ask=Close[index];
      double Bid=Close[index];
      SeriesTest=ArrayGetAsSeries(Spread);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      Bid+=_Point*Spread[index];
      string sAsk=DoubleToString(Ask,_Digits);
      string sBid=DoubleToString(Bid,_Digits);
      string sPeriod=GetStringTimeframe(ChartPeriod());
      if(SignMode==MODE_SIGNAL || (SignMode==MODE_TREND && ColorArray[index1]!=ColorIndex))
        {
         if(SoundON) Alert("Sinyal SELL \n Ask=",Ask,"\n Bid=",Bid,"\n waktu=",text,"\n Simbol=",Symbol()," Periode=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": Peringatan sinyal SELL","Sinyal SELL di Ask="+sAsk+", Bid="+sBid+", Tanggal="+text+" Simbol="+Symbol()+" Periode="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": Sinyal SELL di Ask="+sAsk+", Bid="+sBid+", Tanggal="+text+" Simbol="+Symbol()+" Periode="+sPeriod);
        }
      else
        {
         if(SoundON) Alert("Sinyal Down Trend \n Ask=",Ask,"\n Bid=",Bid,"\n waktu=",text,"\n Simbol=",Symbol()," Periode=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": Peringatan sinyal Down Trend","Sinyal SELL di Ask="+sAsk+", Bid="+sBid+", Tanggal="+text+" Simbol="+Symbol()+" Periode="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": Sinyal Down Trend di Ask="+sAsk+", Bid="+sBid+", Tanggal="+text+" Simbol="+Symbol()+" Periode="+sPeriod);
        }
     }
//---
  }
//+------------------------------------------------------------------+
//| Mendapatkan periode waktu sebagai string |
//+------------------------------------------------------------------+
string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)
  {
//----
   return(StringSubstr(EnumToString(timeframe),7,-1));
//----
  }
Menambahkan beberapa panggilan ke fungsi BuySignal() dan SellSignal() setelah siklus perhitungan indikator di blok OnCalculate()
//---
   BuySignal("ColorXdinMA_Alert",ColorXdinMA,1,rates_total,prev_calculated,close,spread);
   SellSignal("ColorXdinMA_Alert",ColorXdinMA,2,rates_total,prev_calculated,close,spread);
//---

Di mana ColorXdinMA adalah nama dari buffer indeks warna untuk menyimpan warna indikator. Nilai 1 dan 2 adalah nomor warna dalam buffer ini, di mana moving average sedang naik atau turun, masing-masing.

Diperkirakan hanya satu panggilan untuk fungsi BuySignal() dan SellSignal() yang akan digunakan di dalam blok OnCalculate() dari kode indikator ini.

Indikator ini menggunakan kelas dari pustaka SmoothAlgorithms.mqh (salin ke <folder_data_terminal>\\MQL5\Include). Penggunaan kelas tersebut telah dijelaskan secara rinci dalam artikel "Rata-Rata Seri Harga untuk Perhitungan Intermediate Tanpa Menggunakan Buffer Tambahan".

Gambar 1. Indikator ColorXdinMA_Alert di grafik

Gambar 2. Indikator ColorXdinMA_Alert. Menghasilkan notifikasi untuk sinyal breakout

Gambar 3. Indikator ColorXdinMA_Alert. Menghasilkan notifikasi untuk sinyal trend

ColorXdinMA_Alert: Indikator Trend dengan Notifikasi untuk MetaTrader 5

Postingan terkait