ColorXdinMA_Alert: Indicador de Tendencia para MetaTrader 5 con Alertas

Autor Original: dimeon

El ColorXdinMA es un indicador de media móvil que incluye alertas, permitiendo enviar correos electrónicos y notificaciones push a dispositivos móviles.

A continuación, te explico las modificaciones realizadas en el código del indicador para implementar las alertas, mensajes de correo y notificaciones push:

Se declara la enumeración para las opciones de generación de señales a nivel global antes de definir las variables de entrada.
//+----------------------------------------------------+
//| Enumeración para las opciones de generación de señales |
//+----------------------------------------------------+
enum ENUM_SIGNAL_MODE
  {
   MODE_SIGNAL,  // Señales de ruptura
   MODE_TREND    // Señales de ruptura y tendencia
  };
Se introducen nuevos parámetros de entrada
//---- Variables de entrada para alertas
input ENUM_SIGNAL_MODE SignMode=MODE_SIGNAL; // Modo de generación de señales
input uint NumberofBar=1;                    // Número de la barra para generar una señal
input bool SoundON=true;                     // Habilitar alertas
input uint NumberofAlerts=2;                 // Número de alertas
input bool EMailON=false;                    // Habilitar envío de señales por correo
input bool PushON=false;                     // Habilitar envío de señales a dispositivos móviles
Se agregaron tres nuevas funciones al final del código del indicador: BuySignal(), SellSignal() y GetStringTimeframe()
//+------------------------------------------------------------------+
//| Función de señal de compra |
//+------------------------------------------------------------------+
void BuySignal(string SignalSirname,// texto del nombre del indicador para correos y mensajes push
               double &ColorArray[],// búfer de índice de color
               int ColorIndex,// índice de color en el búfer de índice de color para generar una señal
               const int Rates_total,     // el número actual de barras
               const int Prev_calculated, // el número de barras en el tick anterior
               const double &Close[],     // precio de cierre
               const int &Spread[])       // spread
  {
//---
   static uint counter=0;
   if(Rates_total!=Prev_calculated) counter=0;

   bool BuySignal=false;
   bool SeriesTest=ArrayGetAsSeries(ColorArray);
   int index,index1;
   if(SeriesTest)
     {
      index=int(NumberofBar);
      index1=index+1;
     }
   else
     {
      index=Rates_total-int(NumberofBar)-1;
      index1=index-1;
     }
   if(SignMode==MODE_SIGNAL)
     {
      if(ColorArray[index1]!=ColorIndex && ColorArray[index]==ColorIndex) BuySignal=true;
     }
   else
     {
      if(ColorArray[index]==ColorIndex) BuySignal=true;
     }
   if(BuySignal && counter<=NumberofAlerts)
     {
      counter++;
      MqlDateTime tm;
      TimeToStruct(TimeCurrent(),tm);
      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
      SeriesTest=ArrayGetAsSeries(Close);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      double Ask=Close[index];
      double Bid=Close[index];
      SeriesTest=ArrayGetAsSeries(Spread);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      Bid+=_Point*Spread[index];
      string sAsk=DoubleToString(Ask,_Digits);
      string sBid=DoubleToString(Bid,_Digits);
      string sPeriod=GetStringTimeframe(ChartPeriod());
      if(SignMode==MODE_SIGNAL || (SignMode==MODE_TREND && ColorArray[index1]!=ColorIndex))
        {
         if(SoundON) Alert("Señal de COMPRA Ask=",Ask," Bid=",Bid," currtime=",text," Símbolo=",Symbol()," Period=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": Alerta de señal de COMPRA","Señal de COMPRA en Ask="+sAsk+", Bid="+sBid+", Fecha="+text+" Símbolo="+Symbol()+" Period="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": Señal de COMPRA en Ask="+sAsk+", Bid="+sBid+", Fecha="+text+" Símbolo="+Symbol()+" Period="+sPeriod);
        }
      else
        {
         if(SoundON) Alert("Señal de tendencia alcista Ask=",Ask," Bid=",Bid," currtime=",text," Símbolo=",Symbol()," Period=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": Alerta de señal de tendencia alcista","Señal de COMPRA en Ask="+sAsk+", Bid="+sBid+", Fecha="+text+" Símbolo="+Symbol()+" Period="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": Señal de tendencia alcista en Ask="+sAsk+", Bid="+sBid+", Fecha="+text+" Símbolo="+Symbol()+" Period="+sPeriod);
        }
     }

//---
  }
//+------------------------------------------------------------------+
//| Función de señal de venta |
//+------------------------------------------------------------------+
void SellSignal(string SignalSirname,// texto del nombre del indicador para correos y mensajes push
                double &ColorArray[],       // búfer de índice de color
                int ColorIndex,             // índice de color en el búfer de índice de color para generar una señal
                const int Rates_total,     // el número actual de barras
                const int Prev_calculated, // el número de barras en el tick anterior
                const double &Close[],     // precio de cierre
                const int &Spread[])       // spread
  {
//---
   static uint counter=0;
   if(Rates_total!=Prev_calculated) counter=0;

   bool SellSignal=false;
   bool SeriesTest=ArrayGetAsSeries(ColorArray);
   int index,index1;
   if(SeriesTest)
     {
      index=int(NumberofBar);
      index1=index+1;
     }
   else
     {
      index=Rates_total-int(NumberofBar)-1;
      index1=index-1;
     }

   if(SignMode==MODE_SIGNAL)
     {
      if(ColorArray[index1]!=ColorIndex && ColorArray[index]==ColorIndex) SellSignal=true;
     }
   else
     {
      if(ColorArray[index]==ColorIndex) SellSignal=true;
     }
   if(SellSignal && counter<=NumberofAlerts)
     {
      counter++;
      MqlDateTime tm;
      TimeToStruct(TimeCurrent(),tm);
      string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
      SeriesTest=ArrayGetAsSeries(Close);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      double Ask=Close[index];
      double Bid=Close[index];
      SeriesTest=ArrayGetAsSeries(Spread);
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      Bid+=_Point*Spread[index];
      string sAsk=DoubleToString(Ask,_Digits);
      string sBid=DoubleToString(Bid,_Digits);
      string sPeriod=GetStringTimeframe(ChartPeriod());
      if(SignMode==MODE_SIGNAL || (SignMode==MODE_TREND && ColorArray[index1]!=ColorIndex))
        {
         if(SoundON) Alert("Señal de VENTA Ask=",Ask," Bid=",Bid," currtime=",text," Símbolo=",Symbol()," Period=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": Alerta de señal de VENTA","Señal de VENTA en Ask="+sAsk+", Bid="+sBid+", Fecha="+text+" Símbolo="+Symbol()+" Period="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": Señal de VENTA en Ask="+sAsk+", Bid="+sBid+", Fecha="+text+" Símbolo="+Symbol()+" Period="+sPeriod);
        }
      else
        {
         if(SoundON) Alert("Señal de tendencia bajista Ask=",Ask," Bid=",Bid," currtime=",text," Símbolo=",Symbol()," Period=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": Alerta de señal de tendencia bajista","Señal de VENTA en Ask="+sAsk+", Bid="+sBid+", Fecha="+text+" Símbolo="+Symbol()+" Period="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": Señal de tendencia bajista en Ask="+sAsk+", Bid="+sBid+", Fecha="+text+" Símbolo="+Symbol()+" Period="+sPeriod);
        }
     }
//---
  }
//+------------------------------------------------------------------+
//| Obtener el marco de tiempo como cadena |
//+------------------------------------------------------------------+
string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)
  {
//----
   return(StringSubstr(EnumToString(timeframe),7,-1));
//----
  }
Se agregan un par de llamadas a las funciones BuySignal() y SellSignal() después de los ciclos de cálculo del indicador en el bloque OnCalculate()
//---
   BuySignal("ColorXdinMA_Alert",ColorXdinMA,1,rates_total,prev_calculated,close,spread);
   SellSignal("ColorXdinMA_Alert",ColorXdinMA,2,rates_total,prev_calculated,close,spread);
//---

Donde ColorXdinMA es el nombre del búfer de índice de color para almacenar los colores del indicador. Los valores 1 y 2 corresponden a los números de colores en este búfer, en los que la media móvil está ascendiendo o descendiendo, respectivamente.

Se asume que solo se utilizará una llamada a las funciones BuySignal() y SellSignal() en el bloque OnCalculate() del código del indicador.

El indicador utiliza las clases de la biblioteca SmoothAlgorithms.mqh (cópiala en <terminal_data_folder>\MQL5\Include). El uso de las clases se describe en detalle en el artículo "Promediando Series de Precios para Cálculos Intermedios Sin Usar Buffers Adicionales".

Fig1. El indicador ColorXdinMA_Alert en el gráfico

Fig.2. El indicador ColorXdinMA_Alert. Generando alerta para señal de ruptura

Fig.3. El indicador ColorXdinMA_Alert. Generando alerta para señal de tendencia

ColorXdinMA_Alert: Indicador de Tendencia para MetaTrader 5 con Alertas

Publicaciones relacionadas